Contents

This documentation is Copyright 1988 by Peter Barella, Copyright 2000 Perette Barella. All rights are reserved. Peter Barella, and anyone else connected with PB Dos or this documentation, disclaim responsibility from use of the information contained herein. We are not liable for the effects of use or misuse of this manual, regardless of its accuracy, or results caused by use of information contained herein.

1. Text formats

2. PB Basic

PB Basic is a special version of Basic which allows you to access all of the RS-Dos command set, and access most PB Dos features as well. To enter PB Basic from the PB Dos Ready prompt, type: 
BASIC
If you want to execute a specific program on entry to PB Basic, add the name of the program to the end of the command. So, if you wanted to run a Basic program called TERMINAL, you would enter 
BASIC TERMINAL

2.1. PB Basic Commands

PB Basic adds a lot of new commands to RS-Dos, and adds some new formats to others. Here is a brief summary of all the commands. If you don't understand some of them, a more detailed explanation will be provided in a following section.

2.2. PB Basic Functions

3. PB Dos Commands

4. Building a PB-Dos boot disk

This program is provided for reference only. It is the program used to build the image file, which you will need to download.

File: GETIMAGE.BAS

1 ' This program builds the image file from an existing Pb-Dos boot disk.
3 CLEAR 7000:DIM A$(16),B$(16)
4 ON ERROR GOTO 5:KILL "BOOTIMAG.DAT":ON ERROR GOTO
5 OPEN "R", #1, "BOOTIMAG", 256
8 FIELD #1, 128 AS P1$, 128 AS P2$
10 FOR T=0 TO 6
15 IF T=6 THEN T=34
17 PRINT STRING$(POS (0), 8); "TRACK:";T;
20 FOR S=1 TO 16
25 DSKI$ 0,T,S,A$(S),B$(S)
30 NEXT S
35 FOR S=1 TO 16
40 LSET P1$=A$(S):LSET P2$=B$(S)
50 PUT #1
60 NEXT S,T
70 CLOSE #1
75 PRINT
80 END
This program puts the image file into place on a disk. It can be run under RS-Dos.

File: PUTIMAGE.BAS

10 ' PB-DOS IMAGE FILE TO BOOT DISK BUILDER
15 ' (C) 2000 PERETTE BARELLA, FORMERLY PETER BARELLA
20 ' PUBLIC DOMAIN.
25 ' TAKE A DISK.  PUT THE IMAGE FILE ON IT, THEN
30 ' RUN THIS PROGRAM.  THIS PROGRAM WILL DEALLOCATE
35 ' THE APPROPRIATE TRACKS IN THE GRANULE ALLOCATION
40 ' TABLE, THEN TRANSFER THE IMAGE FROM FILE ONTO
45 ' THOSE TRACKS.
50 CLEAR 7000
55 DSKI$ 0,17,2,A$,B$
60 IF LEFT$(A$,12) <> STRING$(12,255) THEN PRINT "TRACKS 0-5 NOT EMPTY.":END
65 IF MID$(A$,67,2) <> STRING$(2,255) THEN PRINT "TRACK 34 IS NOT EMPTY.":END
70 MID$(A$,1,12)=STRING$(12,0)
75 MID$(A$,67,2)=STRING$(2,0)
80 DSKO$ 0,17,2,A$,B$
100 DIM A$(16),B$(16)
120 OPEN "R", #1, "BOOTIMAG", 256
130 FIELD #1, 128 AS P1$, 128 AS P2$
140 FOR T=0 TO 6
150 IF T=6 THEN T=34
160 PRINT STRING$(POS (0), 8); "TRACK:";T;
170 FOR S=1 TO 16
175 GET #1
180 A$(S)=P1$:B$(S)=P2$
190 NEXT S
200 FOR S=1 TO 16
210 DSKO$ 0,T,S,A$(S),B$(S)
230 NEXT S,T
240 CLOSE #1
250 PRINT
260 END
Once you've downloaded the image, put it on a fresh, blank disc. Then type in/download PUTIMAGE, and run it. When complete, copy PBDOS.BIN onto the disc. Also put PBDOS.BAS in ASCII format on the disc. Do NOT load PBDOS.BAS, then save it to the disc without ",A" option (on CoCo-2, tokenization is incomplete. On CoCo-3, tokenization is partially wrong and partially incomplete).

Type "DOS" to boot. Or, if using Disk Basic 1.0, download the "+.BAS" program, save it on the boot disc, then run that in lieu of the DOS command.

Pb-Dos will boot and ask for the time. After entry, PBDOS.BAS will be run. At "PB Dos Ready", type Clear-Break, then:

SAVE "PBDOS"
RUN
BOOTNAME
Perette Barella
NAME :0 Perette's PB-Dos Boot Disc
Substitute your name for mine. Though the process is not complete, now would be a good time to restart the machine, make a backup, then once again boot Pb-Dos.

Next, put the rest of the Pb-Dos files on the disc.

This completes the creation of your Pb-Dos boot disc.

4.1. Techie Boot details

What PUTIMAGE does is to put BASIC on tracks 0-5, and a boot program on track 34. BASIC is stored in 4K chunks using sectors 1-16 of each track, $8000-$8FFF=track 0, $9xxx=track 1, ..., $Dxxx=track5. The necessary revisions are BASIC 1.1, Extended BASIC 1.1, and Disk BASIC 1.1. The CoCo-3 ROMS are not used and the region they occupy is taken by Pb-Dos.

The boot program on track 34 loads the ROMs from disc into low RAM, initiates all-RAM mode, copies them into their correct address spaces, adds a jump back into the boot program somewhere near the end of Disc BASIC's initialization, then jumps into BASIC as if a reset was occuring.

When the boot program gets control back, it asks Disc BASIC to load PBDOS.BIN, which is executed immediately thereafter. This piece of code installs hooks throughout the various ROMs, then displays the copyright screen and owner, and prompts for the date. After date entry, the autorun sector is read and put in the type-ahead buffer for execution (this can be overriden with Clear-Zero). Finally, the initialization code turns itself into a printer spool buffer and executes PBDOS.BAS.


Page URL: http://www.barella.org/Perette/OpenSource/CoCo/PbDos/pbdos-docs.html
Revision information:
@(#) stddefs.m4 built 2005-05-05 13:08:55 by makeinc $Revision: 1.11 $
@(#) $Id: toc.m4,v 1.7 2004/01/02 03:29:33 perette Exp $
@(#) $Id$
@(#) $Id: html.m4,v 1.44 2005/05/08 04:04:59 perette Exp $